您現在的位置:程序化交易>> 期貨公式>> 交易開拓者(TB)>> 開拓者公式>>正文內容

            海龜系統改進后的策略源碼[開拓者公式]

            • 源碼內容:


              Params
                  Numeric RiskRatio(1);                   // % Risk Per N ( 0 - 100)
                  Numeric ATRLength(20);                  // 平均波動周期 ATR Length
                  Numeric boLength(20);                   // 短周期 BreakOut Length
                  Numeric fsLength(55);                   // 長周期 FailSafe Length
                  Numeric teLength(10);                   // 離市周期 Trailing Exit Length
                  Bool LastProfitableTradeFilter(True);   // 使用入市過濾條件
              Vars
                      Numeric MinPoint;                       // 最小變動單位
                      NumericSeries AvgTR;                                        // ATR
                  Numeric N;                              // N 值
                  Numeric TotalEquity;                    // 按最新收盤價計算出的總資產
                  Numeric TurtleUnits;                    // 交易單位
                  NumericSeries DonchianHi;                      // 唐奇安通道上軌,延后1個Bar
                  NumericSeries DonchianLo;                      // 唐奇安通道下軌,延后1個Bar
                  NumericSeries fsDonchianHi;                    // 唐奇安通道上軌,延后1個Bar,長周期
                  NumericSeries fsDonchianLo;                    // 唐奇安通道下軌,延后1個Bar,長周期
                  Numeric ExitHighestPrice;               // 離市時判斷需要的N周期最高價
                  Numeric ExitLowestPrice;                // 離市時判斷需要的N周期最低價
                  Numeric myEntryPrice;                   // 開倉價格
                  Numeric myExitPrice;                    // 平倉價格
                  Bool SendOrderThisBar(False);                  // 當前Bar有過交易
                      NumericSeries preEntryPrice(0);               // 前一次開倉的價格
                      BoolSeries PreBreakoutFailure(false);        // 前一次突破是否失敗
              Begin
                  If(BarStatus == 0)
                  {
                              preEntryPrice = InvalidNumeric;
                              PreBreakoutFailure = false;
                      }       
                     
                      MinPoint = MinMove*PriceScale;
                  AvgTR = XAverage(TrueRange,ATRLength);
                      N = AvgTR[1];       
                  TotalEquity = Portfolio_CurrentCapital() + Portfolio_UsedMargin();
                  TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
                  TurtleUnits = IntPart(TurtleUnits); // 對小數取整

                  DonchianHi = HighestFC(High[1],boLength);
                  DonchianLo = LowestFC(Low[1],boLength);

                      fsDonchianHi = HighestFC(High[1],fsLength);
                  fsDonchianLo = LowestFC(Low[1],fsLength);
                     
                      ExitLowestPrice = LowestFC(Low[1],teLength);
                      ExitHighestPrice = HighestFC(High[1],teLength);

                      Commentary("N="+Text(N));
                      Commentary("preEntryPrice="+Text(preEntryPrice));
                      Commentary("PreBreakoutFailure="+IIFString(PreBreakoutFailure,"True","False"));
                     
                  // 當不使用過濾條件,或者使用過濾條件并且條件為PreBreakoutFailure為True進行后續操作
                  If(MarketPosition == 0 && ((!LastProfitableTradeFilter) Or (PreBreakoutFailure)))
                  {
                      // 突破開倉
                      If(High > DonchianHi && TurtleUnits >= 1)
                      {
                          // 開倉價格取突破上軌+一個價位和最高價之間的較小值,這樣能更接近真實情況,并能盡量保證成交
                          myEntryPrice = min(high,DonchianHi + MinPoint);
                          myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的時候用開盤價代替
                                      preEntryPrice = myEntryPrice;
                          Buy(TurtleUnits,myEntryPrice);
                                      SendOrderThisBar = True;
                                      PreBreakoutFailure = False;
                      }

                      If(Low < DonchianLo && TurtleUnits >= 1)
                      {
                          // 開倉價格取突破下軌-一個價位和最低價之間的較大值,這樣能更接近真實情況,并能盡量保證成交
                          myEntryPrice = max(low,DonchianLo - MinPoint);
                          myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的時候用開盤價代替
                          preEntryPrice = myEntryPrice;
                          SendOrderThisBar = True;
                          SellShort(TurtleUnits,myEntryPrice);
                                      SendOrderThisBar = True;
                                      PreBreakoutFailure = False;
                      }
                  }

                  // 長周期突破開倉 Failsafe Breakout point
                  If(MarketPosition == 0)
                  {
                              Commentary("fsDonchianHi="+Text(fsDonchianHi));
                      If(High > fsDonchianHi && TurtleUnits >= 1)
                      {
                          // 開倉價格取突破上軌+一個價位和最高價之間的較小值,這樣能更接近真實情況,并能盡量保證成交
                          myEntryPrice = min(high,fsDonchianHi + MinPoint);
                          myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的時候用開盤價代替
                                      preEntryPrice = myEntryPrice;
                          Buy(TurtleUnits,myEntryPrice);
                                      SendOrderThisBar = True;
                                      PreBreakoutFailure = False;
                      }

                              Commentary("fsDonchianLo="+Text(fsDonchianLo));
                      If(Low < fsDonchianLo && TurtleUnits >= 1)
                      {
                          // 開倉價格取突破下軌-一個價位和最低價之間的較大值,這樣能更接近真實情況,并能盡量保證成交
                          myEntryPrice = max(low,fsDonchianLo - MinPoint);
                          myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的時候用開盤價代替
                          preEntryPrice = myEntryPrice;
                          SellShort(TurtleUnits,myEntryPrice);
                                      SendOrderThisBar = True;
                                      PreBreakoutFailure = False;
                      }
                  }

                  If(MarketPosition == 1) // 有多倉的情況
                  {      
                              Commentary("ExitLowestPrice="+Text(ExitLowestPrice));
                      If(Low < ExitLowestPrice)
                      {
                          myExitPrice = max(Low,ExitLowestPrice - MinPoint);
                                      myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // 大跳空的時候用開盤價代替
                          Sell(0,myExitPrice);    // 數量用0的情況下將全部平倉
                      }Else
                      {
                          If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
                          {
                              If(Open >= preEntryPrice + 0.5*N) // 如果開盤就超過設定的1/2N,則直接用開盤價增倉。
                              {
                                  myEntryPrice = Open;
                                                      preEntryPrice = myEntryPrice;
                                  Buy(TurtleUnits,myEntryPrice);
                                                      SendOrderThisBar = True;
                              }

                              while(High >= preEntryPrice + 0.5*N) // 以最高價為標準,判斷能進行幾次增倉
                              {
                                  myEntryPrice = preEntryPrice + 0.5 * N;
                                  preEntryPrice = myEntryPrice;
                                  Buy(TurtleUnits,myEntryPrice);
                                                      SendOrderThisBar = True;                                       
                              }
                          }
                                     
                          // 止損指令
                                      If(Low <= preEntryPrice - 2 * N && SendOrderThisBar == false) // 加倉Bar不止損
                                      {
                                              myExitPrice = preEntryPrice - 2 * N;
                                              Sell(0,myExitPrice); // 數量用0的情況下將全部平倉
                                              PreBreakoutFailure = True;
                                      }
                      }
                  }Else If(MarketPosition ==-1) // 有空倉的情況
                  {
                      // 求出持空倉時離市的條件比較值        
                              Commentary("ExitHighestPrice="+Text(ExitHighestPrice));
                      If(High > ExitHighestPrice)
                      {
                          myExitPrice = Min(High,ExitHighestPrice + MinPoint);
                                      myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // 大跳空的時候用開盤價代替
                          BuyToCover(0,myExitPrice);    // 數量用0的情況下將全部平倉
                      }Else
                      {
                          If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
                          {
                              If(Open <= preEntryPrice - 0.5*N) // 如果開盤就超過設定的1/2N,則直接用開盤價增倉。
                              {
                                  myEntryPrice = Open;
                                                      preEntryPrice = myEntryPrice;
                                  SellShort(TurtleUnits,myEntryPrice);
                                                      SendOrderThisBar = True;
                              }

                              while(Low <= preEntryPrice - 0.5*N) // 以最低價為標準,判斷能進行幾次增倉
                              {
                                  myEntryPrice = preEntryPrice - 0.5 * N;
                                  preEntryPrice = myEntryPrice;
                                  SellShort(TurtleUnits,myEntryPrice);
                                                      SendOrderThisBar = True;
                              }
                          }

                          // 止損指令
                                      If(High >= preEntryPrice + 2 * N &&SendOrderThisBar==false) // 加倉Bar不止損
                                      {
                                              myExitPrice = preEntryPrice + 2 * N;
                                              BuyToCover(0,myExitPrice); // 數量用0的情況下將全部平倉
                                              PreBreakoutFailure = True;
                                      }
                      }
                  }
              End

               

             

            有思路,想編寫各種指標公式,程序化交易模型,選股公式,預警公式的朋友

            可聯系技術人員 QQ: 262069696  點擊在線交流進行 有償 編寫!不貴!點擊查看價格!

             


            【字體: 】【打印文章】【查看評論

            相關文章

              沒有相關內容
              性熟妇XIDEOS另类HD_日本熟妇裸交ⅩXX视频_99RE66在线观看精品免费_AV无码网址_亚洲中文AⅤ中文字幕 免费无码又爽又刺激高潮 国产在线精品一区二区高清不卡 JIZZJIZZ无码中国在线观 我的公强要了我高潮在线观看 亚洲中文字幕无码不卡电影 久久久WWW影院人成_免费 99久久99久久精品国产片 凸凹人妻人人澡人人添 亚洲AV无码国产精品久久 国产在线精品一区二区三区直播